#
# Copyright 2021 The Android Open Source Project
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
# MODIFIED for Lumenoir (2026) from androidx/media tag 1.11.1,
# libraries/decoder_ffmpeg/src/main/jni/CMakeLists.txt:
#  - links the prebuilt LGPL *shared* FFmpeg libraries (IMPORTED SHARED targets, which the
#    Android Gradle Plugin packages into the APK next to libffmpegJNI.so) instead of static ones,
#    so they can be replaced by the user as the LGPL requires;
#  - headers and libraries come from ${FFMPEG_ROOT} (third_party/ffmpeg, produced by
#    tools/ffmpeg/build_ffmpeg.sh) instead of src/main/jni/ffmpeg;
#  - 16 KB page-aligned link;
#  - adds mvhevc_jni.cc (Lumenoir): MV-HEVC spatial video, both eyes side by side.

cmake_minimum_required(VERSION 3.21.0 FATAL_ERROR)

# Enable C++11 features.
set(CMAKE_CXX_STANDARD 11)

project(libffmpegJNI C CXX)

if(NOT DEFINED FFMPEG_ROOT)
    set(FFMPEG_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/../../../../../third_party/ffmpeg")
endif()
set(ffmpeg_include "${FFMPEG_ROOT}/include")
set(ffmpeg_binaries "${FFMPEG_ROOT}/lib/${ANDROID_ABI}")

if(NOT EXISTS "${ffmpeg_include}/libavcodec/avcodec.h")
    message(FATAL_ERROR "FFmpeg headers not found in ${ffmpeg_include}; run tools/ffmpeg/build_ffmpeg.sh")
endif()

foreach(ffmpeg_lib avutil swresample avcodec)
    set(ffmpeg_lib_file_path ${ffmpeg_binaries}/lib${ffmpeg_lib}.so)
    if(NOT EXISTS "${ffmpeg_lib_file_path}")
        message(FATAL_ERROR "${ffmpeg_lib_file_path} not found; run tools/ffmpeg/build_ffmpeg.sh")
    endif()
    add_library(
            ${ffmpeg_lib}
            SHARED
            IMPORTED)
    set_target_properties(
            ${ffmpeg_lib} PROPERTIES
            IMPORTED_LOCATION
            ${ffmpeg_lib_file_path})
endforeach()

include_directories(${ffmpeg_include})
find_library(android_log_lib log)

add_library(ffmpegJNI
            SHARED
            ffmpeg_jni.cc
            mvhevc_jni.cc)

set_target_properties(ffmpegJNI PROPERTIES
                      CXX_VISIBILITY_PRESET hidden
                      VISIBILITY_INLINES_HIDDEN ON)

target_link_libraries(ffmpegJNI
                      PRIVATE android
                      PRIVATE nativewindow
                      PRIVATE EGL
                      PRIVATE GLESv3
                      PRIVATE swresample
                      PRIVATE avcodec
                      PRIVATE avutil
                      PRIVATE ${android_log_lib})

# Additional flags needed for "arm64-v8a" from NDK 23.1.7779620 and above.
# See https://github.com/google/ExoPlayer/issues/9933#issuecomment-1029775358.
if(ANDROID_ABI STREQUAL "arm64-v8a")
    target_link_options(ffmpegJNI PRIVATE "-Wl,-Bsymbolic")
endif()

# 16 KB page size support (NDK r28 already defaults to it; keep it explicit).
target_link_options(ffmpegJNI PRIVATE "-Wl,-z,max-page-size=16384")
